The outer diameter of the casing is 177.8mm, and the thickness of the casing is 13.72mm. The steel grade of the casing is N80. The yield strength is 551.6MPa. Poisson’s ratio is 0.3. The elastic modulus is 2.06GPa. The curvature of the casing is 6degrees/100m. Perform 3D analysis using SOLID95 elements.

FINISH
/CLEAR
!*****************************
!units: m, Pa
!define parameters
!*****************************
*SET,EX_,2.06E11      !Young's Modulus
*SET,PRXY_,0.3      !Poisson's ratio
*SET,PI,2*ASIN(1)      !pi
*SET,OUTD,177.8E-3      !the outer diameter of the casing
*SET,THICK,13.72E-3      !the thickness of the casing
*SET,INNERD,OUTD-2*THICK      !the inner diameter of the casing
*SET,L_,1      !the length of the casing
*SET,P_,1E6      !the outer pressure
*SET,CUR,6      !the curvature, unit: degree/100m
*SET,I_,PI*(OUTD**4-INNERD**4)/64      !moment of inertia
*SET,F_,(((CUR*PI/180)*L_/100)*EX_*I_)/(L_**2)      !the force that bends the casing

!*****************************
!create geometry
!*****************************
/PREP7
ET,1,95
MP,EX,1,EX_
MP,PRXY,1,PRXY_
CYL4,0,0,OUTD/2,,INNERD/2,,L_

!*****************************
!mesh
!*****************************
SMRTSIZE,4
VSWEEP,ALL

!*****************************
!apply loads and boundary conditions
!*****************************
NSEL,S,LOC,Z,0
D,ALL,ALL
CSYS,1      !cylindrical coordinate system
ASEL,S,LOC,X,OUTD/2      !select the outer surface
SFA,ALL,,PRES,P_
CSYS,0      !default coordinate system
ASEL,S,LOC,Z,L_
NSLA,S,1
*GET,NODECOUNT,NODE,,COUNT      !get the number of nodes
F,ALL,FY,-F_/NODECOUNT      !the force is distributed on every node
ALLSEL,ALL,ALL
FINISH

!*****************************
!solve
!*****************************
/SOLU
SOLVE
FINISH

!*****************************
!post-processing
!*****************************
/POST1
SET,LAST
PLNSOL,S,INT
NSORT,S,INT
*GET,MAXINT,SORT,0,MAX      !get the maximum stress intensity