This is another simple problem of a statically indeterminate truss. 

Bilinear kinetic hardening material model is used. The beauty of this problem is that as the force increases, it can be expected that the vertical member and slant members will develop into the plastic stage consecutively. That will be seen later from the equilibrium path.

BKIN material model

Three LINK180 elements are used to model the truss. The model is loaded by applying a downward 0.01m displacement at K1. When retrieving line element results such as stress and plastic strain, the sequence number method in ESOL command is used. The APDL for this problem is as follows (annotations are in lowercase)

FINISH
/CLEAR
/PREP7
ET,1,LINK180
R,1,1E-4
MP,EX,1,2E11
MP,PRXY,1,0.3
TB,BKIN,1,1,2,1		!bilinear kinetic hardening
TBDATA,1,2E8,2E9	!yield strength and tangent modulus
TBPLOT,BKIN,1
TBLIST,BKIN,1
N,1
N,2,-1,1,0
N,3,0,1,0
N,4,1,1,0
E,1,2
E,1,4
E,1,3
/ESHAPE,1
EPLOT
FINISH
/SOLU
D,2,UX,,,4,1,UY
D,ALL,UZ
D,1,UY,-0.01		!load the truss through displacement
TIME,0.01			!time step=displacement step
NLGEOM,ON
AUTOTS,ON
NSUBST,50,100,50
OUTRES,ALL,ALL
SOLVE
FINISH
/POST26
RFORCE,2,1,F,Y		!variable 2=reaction force at node 1
ESOL,3,1,1,LEPPL,1,E_PLASTIC_1	!variable 3=plastic strain of element 1 (using line element results)
ESOL,4,3,1,LEPPL,1,E_PLASTIC_3	!variable 4=plastic strain of element 3
ESOL,5,1,1,LS,1,STRESS_1		!variable 5=elastic stress of element 1
ESOL,6,3,1,LS,1,STRESS_3		!variable 6=elastic stress of element 3
!plot equilibrium path:
/GROPT,REVY,1
/AXLAB,X,DISPLACEMENT
/AXLAB,Y,LOAD
XVAR,1
PLVAR,2
!plot the development of stress and plastic strain:
/GROPT,REVY,0
/AXLAB,X,DISPLACEMENT
/AXLAB,Y,STRESS
XVAR,1
PLVAR,5,6
/AXLAB,X,DISPLACEMENT
/AXLAB,Y,PLASTIC STRAIN
XVAR,1
PLVAR,3,4

Equilibrium path

The above curve consists of three segments of polyline. The first segment represents the elastic stage. When the vertical displacement is about 0.001m, the vertical member enters the plastic stage, and the slope decreases for the first time. When the vertical displacement is about 0.002m, the inclined member also yields, and the slope (i.e. stiffness) decreases further.

To verify this, the stress development and plastic strain development have also been plotted:

Stress development

Plastic strain development

From the development of plastic strain, element 3 (i.e. the vertical member) enters the plastic stage first when the displacement is 0.001m, followed by element 1 (i.e. the inclined member) when the displacement is 0.002m.