As shown in Fig.1, the outer ring is the casing, and the middle is the drill pipe. The unworn part of the casing is going to be analyzed. The diameter of the drill pipe is 127mm. the outer diameter of the casing is 177.8mm, and the thickness of the casing is 13.72mm. The steel grade of the casing is N80. The yield strength is 551.6MPa. Poisson’s ratio is 0.3. The elastic modulus is 2.06GPa. The eccentricity is 18.5mm. Perform 2D plane strain analysis using PLANE82 elements.

FINISH
/CLEAR
!*****************************
!units: m, Pa
!define parameters
!*****************************
*SET,EX_,2.06E11      !Young's Modulus
*SET,PRXY_,0.3      !Poisson's ratio
*SET,OUTD,177.8E-3      !the outer diameter of the casing
*SET,THICK,13.72E-3      !the thickness of the casing
*SET,INNERD,OUTD-2*THICK      !the inner diameter of the casing
*SET,D_DRILL,127E-3      !the diameter of the drill pipe
*SET,ECCEN,18.5E-3      !the eccentricity
*SET,P_,1E6      !the outer pressure

!*****************************
!create geometry
!*****************************
/PREP7
ET,1,82,,,2      !element behaviour: plane strain
MP,EX,1,EX_
MP,PRXY,1,PRXY_
CYL4,0,0,INNERD/2,,OUTD/2
CYL4,0,ECCEN,D_DRILL/2
ASBA,1,2

!*****************************
!mesh
!*****************************
SMRTSIZE,4
AMESH,ALL

!*****************************
!apply loads and boundary conditions
!*****************************
NSEL,S,LOC,Y,0
D,ALL,UY
NSEL,S,LOC,X,0
D,ALL,UX
CSYS,1      !cylindrical coordinate system
LSEL,S,LOC,X,OUTD/2      !select the outline of the casing
SFL,ALL,PRES,P_
ALLSEL,ALL,ALL
FINISH

!*****************************
!solve
!*****************************
/SOLU
SOLVE
FINISH

!*****************************
!post-processing
!*****************************
/POST1
SET,LAST
PLNSOL,S,INT
NSORT,S,INT
*GET,MAXINT,SORT,0,MAX      !get the maximum stress intensity