Fig.1 Typical glass curtain walls

Some assumptions and simplifications in this problem:

1. Elastic materials
2. Cables are modeled using LINK10 elements with the tension-only option
3. Trusses are modeled using BEAM44 (or BEAM188) elements
4. The glass wall is modeled using SHELL63 elements. Wind load distributes evenly on the surface.

The aim of this problem is to calculate the static response of the glass curtain wall under wind load. Modal analysis and buckling analysis are also carried out. Taking advantage of the geometric feature of the cable-truss structure, LGEN, KGEN, and *DO loop are used when creating the geometry. The APDL of this problem is as follows:

FINISH
/CLEAR

/PREP7
!for cable elements
ET,1,LINK10
R,1,0.000314,0.001061
MP,EX,1,1.5E11
MP,PRXY,1,0.3
MP,DENS,1,7800

!create the geometry of horizontal cables
NUMSTR,KP,1
NUMSTR,LINE,1
NUMSTR,AREA,1
NUMSTR,VOLU,1
CSYS,0
K,1,0,0.3,1
K,2,0,-0.3,1
K,3,2,-0.3,1
K,4,2,0.3,1
L,1,3
L,2,4
LGEN,2,1,2,,2
LGEN,4,1,2,,-2
NUMMRG,ALL
NUMCMP,ALL
KGEN,2,5,,,2,0.3
L,5,13
L,6,13
/VIEW,1,-1,-1,1
/VUP,1,2
/REPLOT
LGEN,5,ALL,,,,,2

!mesh horizontal cable elements
LSEL,ALL
LATT,1,1,1
LESIZE,ALL,,,1
LMESH,ALL

!create the geometry of vertical cables
*DO,I,1,4,1
L,9+(I-1)*13,23+(I-1)*13
L,10+(I-1)*13,22+(I-1)*13
L,9+(I-1)*13,22+(I-1)*13
*ENDDO
KGEN,2,10,,,,0.3,-2
KGEN,2,62,,,,0.3,2
GPLOT
L,66,9
L,66,10
L,61,67
L,62,67
KGEN,2,9,,,,,-2,,0
KGEN,2,61,,,,,2,,0
L,68,9
L,61,69

!mesh vertical cable elements
LSEL,U,TYPE,,1
R,2,0.000314,0.0004244
LATT,1,2,1
LESIZE,ALL,,,1
LMESH,ALL
LGEN,3,ALL,,,4
NUMMRG,ALL
NUMCMP,ALL

!for strut elements
ET,2,BEAM44
KEYOPT,2,2,1
MP,EX,2,2.1E11
MP,PRXY,2,0.3
MP,DENS,2,7800
SECTYPE,1,BEAM,CTUBE
SECDATA,0.021,0.024
R,3,,0.108E-6,0.108E-6
RMORE,,0.108E-6,0.108E-6

!create the geometry of struts
*DO,I,1,4,1
L,14+(I-1)*13,16+(I-1)*13
L,15+(I-1)*13,17+(I-1)*13
L,22+(I-1)*13,23+(I-1)*13
L,18+(I-1)*13,19+(I-1)*13
L,20+(I-1)*13,21+(I-1)*13
L,I*2-1,I*2
L,9,10
*ENDDO

!mesh strut elements
LSEL,U,TYPE,,1
LATT,2,3,2
LESIZE,ALL,,,1
LMESH,ALL

!create the geometry of web members
LGEN,2,126,138,6,,,1
LGEN,2,119,139,20,,,-1
LGEN,2,126,,,,,-1
LGEN,2,139,,,,,-2
LGEN,2,138,,,,,2
L,92,83
L,83,59
L,59,81
L,81,46
L,46,79
L,79,33
L,33,89
L,89,20
L,20,85
L,85,7
L,7,87
L,87,90
LSEL,U,TYPE,,1,2,1
LATT,2,3,2
LESIZE,ALL,,,1
LMESH,ALL

!create the geometry of chords
L,90,86
L,91,87
LGEN,12,160,161,1,,,1
SECTYPE,2,BEAM,CTUBE
SECDATA,0.0405,0.0445
R,4,,0.965E-6,0.965E-6
RMORE,,0.965E-6,0.965E-6
LSEL,U,TYPE,,1,2,1
LATT,2,4,2,,,,2
LESIZE,ALL,,,1
LMESH,ALL
ALLSEL
LGEN,2,140,183,1,4
NUMMRG,ALL
NUMCMP,ALL

!for glass curtain wall elements
ET,3,SHELL63
KEYOPT,3,2,1
KEYOPT,3,6,2
MP,EX,3,0.72E11
MP,PRXY,3,0.21
MP,DENS,3,2650
R,5,0.016
SECTYPE,3,SHELL
SECDATA,0.016,3

!mesh glass curtain wall elements
A,7,9,68,90
AATT,3,5,3,0,3
MSHAPE,0,2D
AMAP,1,7,9,68,90
AGEN,5,1,1,0,2
AGEN,2,1,1,0,-2
AGEN,6,1,6,1,,,2
NUMMRG,ALL
NUMCMP,ALL
/ESHAPE,1
EPLOT

Fig. 6 Details of the model

!static analysis
/SOLU
ANTYPE,0
NLGEOM,ON
LUMPM,ON
SSTIF,ON
ACEL,,,9.81
*DO,I,1,5,1
*DO,J,1,3,1
DK,11+(J-1)+(I-1)*13,UX,0
DK,11+(J-1)+(I-1)*13,UY,0
DK,11+(J-1)+(I-1)*13,UZ,0
*ENDDO
*ENDDO
*DO,I,1,12,1
DK,66+(I-1),UX,0
DK,66+(I-1),UY,0
DK,66+(I-1),UZ,0
*ENDDO
*DO,I,1,4,1
DK,90+(I-1),UX,0
DK,90+(I-1),UY,0
DK,90+(I-1),UZ,0
*ENDDO
*DO,I,1,4,1
DK,106+(I-1),UX,0
DK,106+(I-1),UY,0
DK,106+(I-1),UZ,0
*ENDDO
*DO,I,1,9,1
DK,110+(I-1),UX,0
DK,110+(I-1),UY,0
DK,110+(I-1),UZ,0
*ENDDO
SFA,ALL,1,PRES,600
SOLVE
FINISH

/POST1
PLNSOL,U,Y
PLNSOL,S,EQV
FINISH

!calculate the pre-stress
/SOLU
NLGEOM,OFF
ANTYPE,0
SSTIF,ON
SOLVE
FINISH

!modal analysis
/SOLU
ANTYPE,2
MODOPT,LANB,15
MXPAND,15,,,YES,0.01
PSTRES,ON
SOLVE
FINISH

/POST1
SET,LIST
SET,1,1
PLDISP,0
/TRLCY,ELEM,1,ALL,,,
/REPLOT 
FINISH

!calculate the pre-stress (considering wind pressure)
/SOLU
ANTYPE,0
NLGEOM,OFF
LUMPM,OFF
SFA,ALL,1,PRES,600
ACEL,,,9.81
SSTIF,ON
SOLVE
FINISH

!buckling analysis
/SOLU
ANTYPE,1
BUCOPT,LANB,1,0.01
SOLVE
FINISH

!expand the buckling mode
/SOLU
MXPAND,1,0,1000,YES,0.01
SOLVE
FINISH

ESEL,U,TYPE,,3
/ESHAPE,0
/REPLOT
/POST1
SET,FIRST
PLDISP,0