Construction Simulation of a Prestressed Reinforced Concrete Bridge: Part 1-Geometry and Meshing

/ xutaosun

The geometry of the bridge is directly generated from keypoints to lines and from keypoints to volumes. When meshing the volume, VSWEEP is used to ensure that all concrete elements are hexahedrons. The element size is controlled using LESIZE command and NDIV in L command. 

Prestress rebar is modelled by LINK8 element. Reinforced concrete is modelled by SOLID65. Non-prestressed rebar is considered via rebar specifications for SOLID65, which are input as real constants. 

model 1001

model 1000

The APDL of this project is as follows:

FINISH
/CLEAR
/FILENAME,BRIDGE,1
/TITLE,BRIDGE CONSTRUCTION SIMULATION

/PREP7
H_BASKET=130000*5				!the weight of hanging basket
V_NUM=161						!the number of volumes of the box girder
A_NUM=48						!the number of areas on each volume of the box girder
P_NUM=5							!the number of piers
*DIM,P_BEGIN,ARRAY,P_NUM		!the position numbers of piers (i.e. as opposed to the sequence number of the volumes of the box girder)
*DIM,P_END,ARRAY,P_NUM
P_BEGIN(1)=15,40,79,117,144
P_END(1)=18,45,83,122,147

!define the parameters for creating cross sections
LINK_NUM=6
*DIM,LINK,ARRAY,LINK_NUM
*DIM,LINK_TL,ARRAY,LINK_NUM		!TL=top left
*DIM,LINK_TR,ARRAY,LINK_NUM		!TR=top right
*DIM,LINK_BL,ARRAY,LINK_NUM		!BL=bottom left
*DIM,LINK_BR,ARRAY,LINK_NUM		!BR=bottom right
LINK(1)=10,23,62,100,139,152
LINK_TL(1)=1,11,57,92,137,126
LINK_TR(1)=27,26,66,103,151,162
LINK_BL(1)=1,19,52,90,132,148
LINK_BR(1)=16,33,71,109,143,162
*DIM,B1,ARRAY,V_NUM+1
*DIM,B2,ARRAY,V_NUM+1
*DIM,B3,ARRAY,V_NUM+1
*DIM,B4,ARRAY,V_NUM+1
*DIM,H1,ARRAY,V_NUM+1
*DIM,H2,ARRAY,V_NUM+1
*DIM,H3,ARRAY,V_NUM+1
*DIM,H4,ARRAY,V_NUM+1
*DIM,H5,ARRAY,V_NUM+1
*DIM,H6,ARRAY,V_NUM+1
*DIM,Y0,ARRAY,V_NUM+1
*DIM,Z0,ARRAY,V_NUM+1
K_NUM=24

/VIEW,1,1,1,1   
/ANG,1  
/REP,FAST   

!define material properties
!concrete
MP,EX,1,0.34500E11				!elastic modulus of concrete (at the final stage)
MP,NUXY,1,0.167					!Poisson's ratio of concrete
MP,ALPX,1,0.90000E-5			!coefficient of thermal expansion of concrete
MP,DENS,1,2400					!density of concrete
!rebar
MP,EX,4,0.19500E12
MP,NUXY,4,0.3
MP,ALPX,4,0.12000E-4
MP,DENS,4,7850
!vertical prestressed rebar
MP,EX,5,0.19500E12
MP,NUXY,5,0.3
MP,ALPX,5,0.12000E-4
MP,DENS,5,7850
!transverse prestressed rebar
MP,EX,6,0.20000E12
MP,NUXY,6,0.3
MP,ALPX,6,0.12000E-4
MP,DENS,6,7850
!define the material property of concrete at different ages
*DO,I,40,400
	*IF,I,LT,100,THEN			!when age<100 days
		MP,EX,I,(0.34500E11)*(1-EXP((0-0.4)*(EXP(0.37))*(I-39)))
	*ELSE
		MP,EX,I,0.34500E11
	*ENDIF
	MP,NUXY,I,0.16700
	MP,ALPX,I,0.90000E-5
	MP,DENS,I,2400
*ENDDO

!define real constants
R,1,4,0.0044,0,0,4,0.002
RMORE,90,0,4,0.003,0,90					!the real constants of rebar which include material number, the volume ratio, and the orientation angles
R,5,0.26600E-2,0.61640E-2
R,6,0.42000E-3,0.66120E-2
R,7,0.16090E-2,0.31320E-2
R,8,0.80400E-3,0.31320E-2
R,9,0.16800E-2,0.64620E-2

!entering parameters for geometry creation
*DO,I,1,162,1
	B1(I)=2.88
*ENDDO
*DO,I,1,2,1
	B3(I)=0.89
	H6(I)=0.79
	B4(I)=2.04
	H1(I)=0.5
	H2(I)=0.36
	H4(I)=0.5
	H5(I)=0.33
*ENDDO
B3(3)=1.75
H6(3)=0.51
*DO,I,3,160,1
	B4(I)=1.2
	H1(I)=0.2
	H2(I)=0.66
	H4(I)=0.57
	H5(I)=0.35
*ENDDO
*DO,I,1,3,1
	B2(I)=0.55
*ENDDO
*DO,I,4,12,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,13,21,1
	B2(I)=0.55
	B3(I)=1.75
	H6(I)=0.51
*ENDDO
*DO,I,22,31,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,32,54,1
	B2(I)=0.55
	B3(I)=1.75
	H6(I)=0.51
*ENDDO
*DO,I,55,70,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,71,92,1
	B2(I)=0.55
	B3(I)=1.75
	H6(I)=0.51
*ENDDO
*DO,I,93,108,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,109,131,1
	B2(I)=0.55
	B3(I)=1.75
	H6(I)=0.51
*ENDDO
*DO,I,132,140,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,141,149,1
	B2(I)=0.55
	B3(I)=1.75
	H6(I)=0.51
*ENDDO
*DO,I,150,159,1
	B2(I)=0.4
	B3(I)=1.9
	H6(I)=0.61
*ENDDO
*DO,I,160,162,1
	B2(I)=0.55
*ENDDO
B3(160)=1.75
H6(160)=0.51
*DO,I,161,162,1
	B3(I)=0.89
	H6(I)=0.79
	B4(I)=2.04
	H1(I)=0.5
	H2(I)=0.36
	H4(I)=0.5
	H5(I)=0.33
*ENDDO
!H3 is the height of the vertex of each cross section
*DO,I,1,24,1
	H3(I)=1.77
*ENDDO
H3(25)=1.8,1.87,1.98,2.13,2.32,2.55,2.81,3.08,3.38,3.7
H3(35)=4.06,4.39,4.75,5.12,5.52,5.94,5.96,5.96,5.96
H3(44)=5.96,5.96,5.94,5.52,5.12,4.75,4.39,4.06,3.7,3.38
H3(54)=3.08,2.81,2.55,2.32,2.13,1.98,1.87,1.8,1.77,1.77
H3(64)=1.8,1.87,1.98,2.13,2.32,2.55,2.81,3.08,3.38,3.7
H3(74)=4.06,4.39,4.75,5.12,5.52,5.94,5.96,5.96,5.96
H3(83)=5.96,5.94,5.52,5.12,4.75,4.39,4.06,3.7,3.38
H3(92)=3.08,2.81,2.55,2.32,2.13,1.98,1.87,1.8,1.77,1.77
H3(102)=1.8,1.87,1.98,2.13,2.32,2.55,2.81,3.08,3.38,3.7
H3(112)=4.06,4.39,4.75,5.12,5.52,5.94,5.96,5.96,5.96
H3(121)=5.96,5.96,5.94,5.52,5.12,4.75,4.39,4.06,3.7,3.38
H3(131)=3.08,2.81,2.55,2.32,2.13,1.98,1.87,1.8
*DO,I,139,162,1
	H3(I)=1.77
*ENDDO
!X0 is the x coordinate of the vertex of each cross section
X0=0
!Z0 is the z coordinate of the vertex of each cross section
Z0(1)=379.34,375.84,372.34,368.84,365.34,361.84,358.34,355.14,352.00,348.50
Z0(11)=346.50,343.00,339.50,336.00,332.50,331.90,330.00,328.10,327.50,324.00
Z0(21)=320.50,317.00,313.50,311.50,307.50,303.50,299.50,295.50,291.50,287.50
Z0(31)=283.50,280.00,276.50,273.00,269.50,266.50,263.50,260.50,257.50,254.50
Z0(41)=253.70,252.10,250.00,248.10,246.50,245.50,242.50,239.50,236.50,233.50
Z0(51)=230.50,227.00,223.50,220.00,216.50,212.50,208.50,204.50,200.50,196.50
Z0(61)=192.50,188.50,186.50,182.50,178.50,174.50,170.50,166.50,162.50,158.50
Z0(71)=155.00,151.50,148.00,144.50,141.50,138.50,135.50,132.50,129.50,128.70
Z0(81)=127.10,122.90,121.30,120.50,117.50,114.50,111.50,108.50,105.50,102.00
Z0(91)=98.50,95.00,91.50,87.50,83.50,79.50,75.50,71.50,67.50,63.50
Z0(101)=61.50,57.50,53.50,49.50,45.50,41.50,37.50,33.50,30.00,26.50
Z0(111)=23.00,19.50,16.50,13.50,10.50,7.50,4.50,3.50,1.90,0.00
Z0(121)=-2.10,-3.70,-4.50,-7.50,-10.50,-13.50,-16.50,-19.50,-23.00,-26.50
Z0(131)=-30.00,-33.50,-37.50,-41.50,-45.50,-49.50,-53.50,-57.50,-61.50,-63.50
Z0(141)=-67.00,-70.50,-74.00,-77.50,-78.10,-80.00,-81.90,-82.50,-86.00,-89.50
Z0(151)=-93.00,-96.50,-98.50,-102.00,-105.14,-108.34,-111.84,-115.34,-118.84,-122.34
Z0(161)=-125.84,-129.70
!Y0 is the y coordinate of the vertex of each cross section
Y0(1)=64.54,64.61,64.67,64.73,64.79,64.85,64.91,64.96,65.01,65.07
Y0(11)=65.10,65.16,65.21,65.26,65.32,65.32,65.35,65.38,65.39,65.44
Y0(21)=65.49,65.54,65.58,65.61,65.66,65.72,65.77,65.81,65.86,65.91
Y0(31)=65.96,66.00,66.03,66.07,66.11,66.14,66.17,66.20,66.23,66.25
Y0(41)=66.26,66.23,66.19,66.26,66.32,66.33,66.36,66.39,66.41,66.43
Y0(51)=66.46,66.48,66.51,66.53,66.55,66.58,66.60,66.63,66.65,66.67
Y0(61)=66.69,66.71,66.72,66.74,66.75,66.77,66.78,66.79,66.80,66.81
Y0(71)=66.82,66.83,66.83,66.84,66.84,66.85,66.85,66.85,66.80,66.81
Y0(81)=66.81,66.81,66.81,66.80,66.85,66.85,66.85,66.84,66.84,66.83
Y0(91)=66.83,66.82,66.81,66.80,66.79,66.78,66.77,66.75,66.74,66.72
Y0(101)=66.71,66.69,66.67,66.65,66.63,66.60,66.58,66.55,66.53,66.51
Y0(111)=66.48,66.46,66.43,66.41,66.39,66.36,66.33,66.32,66.26,66.19
Y0(121)=66.23,66.26,66.25,66.23,66.20,66.17,66.14,66.11,66.07,66.03
Y0(131)=66.00,65.96,65.91,65.86,65.81,65.77,65.72,65.66,65.61,65.58
Y0(141)=65.54,65.49,65.44,65.39,65.38,65.35,65.32,65.32,65.26,65.21
Y0(151)=65.16,65.10,65.07,65.01,64.96,64.91,64.85,64.79,64.73,64.67
Y0(161)=64.61,64.54

!generate keypoints and lines
*DO,J,0,V_NUM,1
	K,1+J*K_NUM,X0-(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1),Z0(J+1)
	K,2+J*K_NUM,X0-(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,3+J*K_NUM,X0-(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,4+J*K_NUM,X0-(B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,5+J*K_NUM,X0-B4(J+1),Y0(J+1),Z0(J+1)
	K,6+J*K_NUM,X0+B4(J+1),Y0(J+1),Z0(J+1)
	K,7+J*K_NUM,X0+(B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,8+J*K_NUM,X0+(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,9+J*K_NUM,X0+(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1),Z0(J+1)
	K,10+J*K_NUM,X0+(B1(J+1)+B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1),Z0(J+1)
	K,11+J*K_NUM,X0+(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1),Z0(J+1)
	K,12+J*K_NUM,X0+(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
	K,13+J*K_NUM,X0+(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
	K,14+J*K_NUM,X0+(B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
	K,15+J*K_NUM,X0-(B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
	K,16+J*K_NUM,X0-(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1),Z0(J+1)
	K,17+J*K_NUM,X0-(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
	K,18+J*K_NUM,X0-(B2(J+1)+B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1),Z0(J+1)
	K,19+J*K_NUM,X0-(B3(J+1)+B4(J+1)),Y0(J+1)-H4(J+1)-H5(J+1),Z0(J+1)
	K,20+J*K_NUM,X0-B4(J+1),Y0(J+1)-H4(J+1),Z0(J+1)
	K,21+J*K_NUM,X0+B4(J+1),Y0(J+1)-H4(J+1),Z0(J+1)
	K,22+J*K_NUM,X0+(B3(J+1)+B4(J+1)),Y0(J+1)-H4(J+1)-H5(J+1),Z0(J+1)
	K,23+J*K_NUM,X0+(B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
	K,24+J*K_NUM,X0-(B3(J+1)+B4(J+1)),Y0(J+1)-H1(J+1)-H2(J+1)-H3(J+1)+H6(J+1),Z0(J+1)
	L_NUM=16
	L,1+J*K_NUM,2+J*K_NUM,2
	L,2+J*K_NUM,3+J*K_NUM,4
	L,3+J*K_NUM,4+J*K_NUM,2
	L,4+J*K_NUM,5+J*K_NUM,2
	L,5+J*K_NUM,6+J*K_NUM,4
	L,6+J*K_NUM,7+J*K_NUM,2
	L,7+J*K_NUM,8+J*K_NUM,2
	L,8+J*K_NUM,9+J*K_NUM,4
	L,9+J*K_NUM,10+J*K_NUM,2
	L,10+J*K_NUM,11+J*K_NUM,4
	L,11+J*K_NUM,12+J*K_NUM,5
	L,12+J*K_NUM,13+J*K_NUM,2
	L,13+J*K_NUM,14+J*K_NUM,2
	L,14+J*K_NUM,15+J*K_NUM,5
	L,15+J*K_NUM,16+J*K_NUM,2
	L,16+J*K_NUM,17+J*K_NUM,2
	L,17+J*K_NUM,18+J*K_NUM,5
	L,18+J*K_NUM,19+J*K_NUM,2
	L,19+J*K_NUM,20+J*K_NUM,2
	L,20+J*K_NUM,21+J*K_NUM,4
	L,21+J*K_NUM,22+J*K_NUM,2
	L,22+J*K_NUM,23+J*K_NUM,5
	L,23+J*K_NUM,24+J*K_NUM,5
	L,24+J*K_NUM,19+J*K_NUM,5
	L,18+J*K_NUM,1+J*K_NUM,4
	*DO,I,26,30,1
		L,I-23+J*K_NUM,I-8+J*K_NUM,2
	*ENDDO
	L,11+J*K_NUM,8+J*K_NUM,2
	L,23+J*K_NUM,12+J*K_NUM,2
	L,23+J*K_NUM,14+J*K_NUM,2
	L,24+J*K_NUM,15+J*K_NUM,2
	L,24+J*K_NUM,17+J*K_NUM,2
	L,11+J*K_NUM,22+J*K_NUM,2
*ENDDO

CM,A_LINE,LINE
VV_NUM=12
!generate volumes
*DO,K,0,V_NUM-1,1
	V,1+K*K_NUM,2+K*K_NUM,3+K*K_NUM,18+K*K_NUM,1+(K+1)*K_NUM,2+(K+1)*K_NUM,3+(K+1)*K_NUM,18+(K+1)*K_NUM
	V,3+K*K_NUM,4+K*K_NUM,19+K*K_NUM,18+K*K_NUM,3+(K+1)*K_NUM,4+(K+1)*K_NUM,19+(K+1)*K_NUM,18+(K+1)*K_NUM
	V,4+K*K_NUM,5+K*K_NUM,20+K*K_NUM,19+K*K_NUM,4+(K+1)*K_NUM,5+(K+1)*K_NUM,20+(K+1)*K_NUM,19+(K+1)*K_NUM
	V,5+K*K_NUM,6+K*K_NUM,21+K*K_NUM,20+K*K_NUM,5+(K+1)*K_NUM,6+(K+1)*K_NUM,21+(K+1)*K_NUM,20+(K+1)*K_NUM
	V,6+K*K_NUM,7+K*K_NUM,22+K*K_NUM,21+K*K_NUM,6+(K+1)*K_NUM,7+(K+1)*K_NUM,22+(K+1)*K_NUM,21+(K+1)*K_NUM
	V,7+K*K_NUM,8+K*K_NUM,11+K*K_NUM,22+K*K_NUM,7+(K+1)*K_NUM,8+(K+1)*K_NUM,11+(K+1)*K_NUM,22+(K+1)*K_NUM
	V,8+K*K_NUM,9+K*K_NUM,10+K*K_NUM,11+K*K_NUM,8+(K+1)*K_NUM,9+(K+1)*K_NUM,10+(K+1)*K_NUM,11+(K+1)*K_NUM
	V,11+K*K_NUM,12+K*K_NUM,23+K*K_NUM,22+K*K_NUM,11+(K+1)*K_NUM,12+(K+1)*K_NUM,23+(K+1)*K_NUM,22+(K+1)*K_NUM
	V,23+K*K_NUM,12+K*K_NUM,13+K*K_NUM,14+K*K_NUM,23+(K+1)*K_NUM,12+(K+1)*K_NUM,13+(K+1)*K_NUM,14+(K+1)*K_NUM
	V,23+K*K_NUM,14+K*K_NUM,15+K*K_NUM,24+K*K_NUM,23+(K+1)*K_NUM,14+(K+1)*K_NUM,15+(K+1)*K_NUM,24+(K+1)*K_NUM
	V,15+K*K_NUM,16+K*K_NUM,17+K*K_NUM,24+K*K_NUM,15+(K+1)*K_NUM,16+(K+1)*K_NUM,17+(K+1)*K_NUM,24+(K+1)*K_NUM
	V,17+K*K_NUM,18+K*K_NUM,19+K*K_NUM,24+K*K_NUM,17+(K+1)*K_NUM,18+(K+1)*K_NUM,19+(K+1)*K_NUM,24+(K+1)*K_NUM
*ENDDO

CMSEL,U,A_LINE
LESIZE,ALL,2
ALLSEL

!mesh
ET,1,65							!3D reinforced concrete solid element
REAL,1
MAT,1
*DO,I,1,V_NUM*VV_NUM,1
	VSWEEP,I
*ENDDO

ET,2,8							!LINK8
*GET,LMAX,LINE,,NUM,MAX			!retrieve the max line number
*DO,I,0,V_NUM,1
	LSEL,NONE
	L,4+K_NUM*I,15+K_NUM*I,1		
	L,7+K_NUM*I,14+K_NUM*I,1		!transverse prestressed rebar	
	MAT,6
	REAL,7
	LESIZE,ALL,,,1
	LMESH,ALL
	LSEL,NONE
	L,1+K_NUM*I,10+K_NUM*I,1		!vertical prestressed rebar
	MAT,5
	REAL,6
	LESIZE,ALL,,,1
	LMESH,ALL,,,1
	LSEL,NONE
*ENDDO

!every ten days, one segment of the box girder is constructed.
ALLSEL
*DO,TENDAY,1,16,1
	LSEL,NONE
	ESEL,NONE
	*IF,TENDAY,LT,5,THEN
		!longitudinal prestressed rebar
		L,18+(P_BEGIN(1)-TENDAY-1)*K_NUM,18+(P_END(1)+TENDAY)*K_NUM
		L,11+(P_BEGIN(1)-TENDAY-1)*K_NUM,11+(P_END(1)+TENDAY)*K_NUM
		L,18+(P_BEGIN(5)-TENDAY-1)*K_NUM,18+(P_END(5)+TENDAY)*K_NUM
		L,11+(P_BEGIN(5)-TENDAY-1)*K_NUM,11+(P_END(5)+TENDAY)*K_NUM
	*ENDIF
	*DO,I,2,4,1
		L,18+(P_BEGIN(I)-TENDAY-1)*K_NUM,18+(P_END(I)+TENDAY)*K_NUM
		L,11+(P_BEGIN(I)-TENDAY-1)*K_NUM,11+(P_END(I)+TENDAY)*K_NUM
	*ENDDO
	TYPE,2
	MAT,5
	REAL,5
	LESIZE,ALL,,,1
	LMESH,ALL
	*IF,TENDAY,LT,5,THEN
		LSEL,NONE
		*IF,TENDAY,EQ,1,THEN
			*DO,I,1,10,1
				LSEL,A,,,LMAX+3*I-2,LMAX+3*I,1			!transverse and vertical prestressed rebar
			*ENDDO
			*DO,I,152,163,1
				LSEL,A,,,LMAX+3*I-2,LMAX+3*I,1
			*ENDDO
		*ENDIF
		LSEL,A,,,LMAX+3*(P_BEGIN(1)-TENDAY)-2,LMAX+3*(P_BEGIN(1)-TENDAY+1),1
		LSEL,A,,,LMAX+3*(P_END(1)-TENDAY)-2,LMAX+3*(P_END(1)-TENDAY+1),1
		LSEL,A,,,LMAX+3*(P_BEGIN(5)-TENDAY)-2,LMAX+3*(P_BEGIN(5)-TENDAY+1),1
		LSEL,A,,,LMAX+3*(P_END(5)-TENDAY)-2,LMAX+3*(P_END(5)-TENDAY+1),1
	*ENDIF
	*DO,I,2,4,1
		LSEL,A,,,LMAX+3*(P_BEGIN(I)-TENDAY)-2,LMAX+3*(P_BEGIN(I)-TENDAY+1),1
		LSEL,A,,,LMAX+3*(P_END(I)-TENDAY)-2,LMAX+3*(P_END(I)-TENDAY+1),1
	*ENDDO
	ESLL,A
	CM,Z_REBAR%TENDAY%,ELEM					!generate components of the prestressed rebar and name them automatically
*ENDDO
*DO,TENDAY,17,19,1
	ALLSEL,ALL
	*IF,TENDAY,EQ,17,THEN
		I1=1
		I2=6
	*ENDIF
	*IF,TENDAY,EQ,18,THEN
		I1=3
		I2=4
	*ENDIF
	*IF,TENDAY,EQ,19,THEN
		I1=2
		I2=5
	*ENDIF
	ESEL,NONE
	MAT,5
	TYPE,2
	REAL,5
	*DO,I,I1,I2,I2-I1
		LSEL,NONE
		REAL,5
		L,K_NUM*(LINK_TL(I)-1)+20,K_NUM*(LINK_TR(I)-1)+20
		L,K_NUM*(LINK_TL(I)-1)+21,K_NUM*(LINK_TR(I)-1)+21
		LESIZE,ALL,,,1
		LMESH,ALL
		LSEL,NONE
		REAL,9
		L,K_NUM*(LINK_BL(I)-1)+17,K_NUM*(LINK_BR(I)-1)+17
		L,K_NUM*(LINK_BL(I)-1)+24,K_NUM*(LINK_BR(I)-1)+24
		L,K_NUM*(LINK_BL(I)-1)+23,K_NUM*(LINK_BR(I)-1)+23
		L,K_NUM*(LINK_BL(I)-1)+12,K_NUM*(LINK_BR(I)-1)+12
		LESIZE,ALL,,,1
		LMESH,ALL
	*ENDDO
	CM,Z_REBAR%TENDAY%,ELEM
*ENDDO
ALLSEL
NUMMRG,NODE
SAVE,,,,MODEL

Leave a comment