We have discussed multiple examples of contact analysis so far. In this post, we are going to investigate a pipe-clamp assembly. By using a pretensioned bolt, the clamp holds the pipe firmly (see the following figure). If the pretension is insufficient, slipping would happen between the pipe and clamp. If the pretension is too large, the pipe may undergo plastic deformation. Therefore, it is necessary to analyze the stress and deformation of the pipe when it is clamped.

One challenge of this example is the simulation of the contact between the pipe and clamp, between the bolt head and clamp, and between the nut and clamp. The other challenge is the application of pretension in the bolt. 

An example of a bolted flange connection was posted previously. These two examples are very similar regarding the above two challenges, although the geometry of the previous example is more complicated. In this example, the geometry was created using UG (Unigraphics), then the x_t file was imported to ANSYS Mechanical through GUI. I tried to attach the x_t file to this post but the file type is not supported on the server. But I will show the APDL after constructing the geometry.

Free meshing (SMRTSIZE) and tetrahedral-shaped SOLID186 elements were used to discretize the model. The mesh is shown in the following figure. Using a level of 5 for smart sizing, the model was discretized into 179116 elements. The computation time was about 22 minutes. As shown in the mesh, it might not be a good idea to include chamfers when creating the geometry. 

The GUI and APDL of this example are given as follows:

GUI: Utility Menu>File>Change Jobname>type in PIPECLAMP

GUI: File>Import>PARA>select the .x_t file

GUI:PlotCtrls>Style>Solid Model Facets>select Normal Faceting

APDL:

/PREP7
ET,1,186
MP,EX,1,2E11
MP,NUXY,1,0.3
MP,DENS,1,7850
MP,MU,2,0.4			!define the coefficient of friction as the 2nd material

!glue bolt and nut
VGLUE,3,4

!mesh
MSHAPE,1,3D
MSHKEY,0
SMRTSIZE,5				
VMESH,ALL

!create and mesh pretension section
PSMESH,1,B100,,VOLU,6,0,Z,,4488,,,B_100		

!create the contact between pipe and clamp
ASEL,S,,,33,36,3
CM,PC_TAR,AREA
ASEL,S,,,7
CM,PC_CON,AREA
ALLSEL
MAT,2
R,1
REAL,1
ET,3,TARGE170
ET,4,CONTA174
KEYOPT,4,9,0
CMSEL,S,PC_TAR
TYPE,3
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL
CMSEL,S,PC_CON
TYPE,4
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL

!create the contact between bolt head and clamp
ASEL,S,,,10
CM,HC_TAR,AREA
ASEL,S,,,49
CM,HC_CON,AREA
ALLSEL
MAT,2
R,2
REAL,2
ET,5,170
ET,6,174
KEYOPT,6,9,0
CMSEL,S,HC_TAR
TYPE,5
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL
CMSEL,S,HC_CON
TYPE,6
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL

!create the contact between nut and clamp
ASEL,S,,,9
CM,NC_TAR,AREA
ASEL,S,,,59
CM,NC_CON,AREA
ALLSEL
MAT,2
R,3
REAL,3
ET,7,170
ET,8,174
KEYOPT,8,9,0
CMSEL,S,NC_TAR
TYPE,7
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL
CMSEL,S,NC_CON
TYPE,8
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLSEL

!settings for solution
/SOLU
ALLSEL
LSCLEAR,ALL
ANTYPE,0
AUTOTS,1
NSUBST,25,100,1
RESCONTROL,,NONE,NONE
OUTRES,ALL,ALL
EQSLV,PCG
TIME,15

!define boundary conditions
ASEL,S,,,37
NSLA,S,1
D,ALL,ALL
ALLSEL

!load step 1: apply pretension to bolt
SLOAD,1,PL01,LOCK,FORC,1000,1,2
!apply constraints
ASEL,S,,,48
NSLA,S,1
D,ALL,UZ
ALLSEL
LSWRITE,1

!load step 2:  the displacement value resulting from the pretension force is locked
LSWRITE,2

!solve
LSSOLVE,1,2,1

!post-processing
/POST1
SET,LAST
PLNSOL,S,EQV,0,1
VSEL,S,,,5,6,1
ESLV,S
PLNSOL,S,EQV,0,1
VSEL,S,,,6				!eqv stress of the bolt
ESLV,S
PLNSOL,S,EQV,1,1
VSEL,S,,,2				!eqv stress of the pipe
ESLV,S
PLNSOL,S,EQV,1,1
ALLSEL
PLDISP,1				!overall deformation

The equivalent stress of the bolt and nut.

The equivalent stress of the bolt.

The deformation and equivalent stress of the pipe.

The overall deformation of the assembly.

By excluding the chamfers and adjusting the normal contact stiffness factor and coefficient of friction, I believe further refinement of the results and better computation speed could be reached.